VB Script ComputersProgramming http://ReliableAnswers.com/x/dqsd/ Shawn K. Hall vbscript Performs Visual Basic Script code interpretation.

Usage:

vbsx [?][:][=][!]vb-script

Switches:

?	-	Return value is to appear in DQSD, like the Debug Window of Visual Basic
=	-	Return value is to replace the text in DQSD, like using Debug.Clear before Debug.Print in Visual Basic
:	-	Return value is to be placed on the clipboard
!	-	Return value is popped in a message box

Supporting Functions:

ClipBoardSetText( sText )	Places sText, a text value, onto the clipboard
ClipBoardGetText()	Obtains the clipboard text data
DebugClear()	Clears the debug window
DebugPrint( sText )	Print data to the debug window, without replacing current content
JoinTo( sArray, ToIndex, Seperator )	'Join's an array to the specified index
RX( sRegEx, sString )	Tests a Regular Expression against a string, returning all matches
-	...add more by editing vbsx.xml to include additional functions within the vbscode <textarea>

Example:

vbsx msgbox("hi")

vbsx !"hi"

vbsx ?Replace("This ugly text", "ugly ", "")

vbsx ClipBoardSetText Replace(ClipBoardGetText, vbCrLf, " ")

vbsx ClipBoardSetText UCase(ClipBoardGetText)

<![CDATA[

Function ClipBoardSetText( sText )
  ClipBoardSetText = window.clipboardData.setData( "Text", sText )
End Function
Function ClipBoardGetText()
  ClipBoardGetText = window.clipboardData.getData( "Text" )
End Function
Sub DebugPrint( sText )
  If Len(document.deff.q.value) = 0 Then
    document.deff.q.value = sText
  Else
    document.deff.q.value = document.deff.q.value & vbCrLf & sText
  End If
End Sub
Sub DebugClear()
  document.deff.q.value = ""
End Sub
Function JoinTo(sArray, ToIndex, Seperator)
  Dim lAt
  If ToIndex > UBound(sArray) Then
    ToIndex = UBound(sArray)
  End If
  For lAt = LBound(sArray) To ToIndex
    JoinTo = JoinTo & Seperator & sArray(lAt)
  Next
  JoinTo = Mid(JoinTo, Len(Seperator) + 1)
End Function
Function RX(sRegEx, sString)
  Dim RE, Match, Matches, sBuild
  Set RE = New RegExp
  RE.Pattern = sRegEx
  RE.IgnoreCase = True
  RE.Global = True
  Set Matches = RE.Execute(sString)
  For Each Match In Matches
    sBuild = sBuild & "Match: @"
    sBuild = sBuild & Match.FirstIndex & ", '"
    sBuild = sBuild & Match.Value & "'" & vbCrLf
  Next
  Set Match = Nothing
  Set Matches = Nothing
  Set RE = Nothing
  RX = sBuild
End Function
Function ProperCase(strInput)
  Dim iPosition, iSpace, strOutput
  iPosition = 1
  Do While InStr(iPosition, strInput, " ", 1) <> 0
    iSpace = InStr(iPosition, strInput, " ", 1)
    strOutput = strOutput & UCase(Mid(strInput, iPosition, 1))
    strOutput = strOutput & LCase(Mid(strInput, iPosition + 1, iSpace - iPosition))
    iPosition = iSpace + 1
  Loop
  strOutput  = strOutput & UCase(Mid(strInput, iPosition, 1))
  strOutput  = strOutput & LCase(Mid(strInput, iPosition + 1))
  ProperCase = strOutput
End Function

]]>